***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Feb 27, 2020                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt MMSZ5256B A K 
.param
+vc0 = 3.006e-11	vc1 = 4.020e-11		vc2 = 1.000		vc3 = 3.625e-11		vc4 = 1.635e-1
+tc1 = 1.521e-2		tc2 = 7.721e-3		tc3 = 5.301e-3		tc4 = 1.201e-2
.func irexp(v) {(vc0+vc1*v^vc2)*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))+(vc3*exp(vc4*v))*(1.0+tc3*(temp-25)*exp(tc4*(temp-25)))}
d1 A K zener
g1 K A value = {irexp(v(K,A))}
.model zener d
***** flag parameter *****
+level = 1 
***** dc model parameter *****
+ is = 1.934e-14	   n = 1.131		  rs = 5.066e-1
+ibv = 4.2e-3		 nbv = 1.0		  bv = 30
+ikf = 5.088e-3
***** capacitance parameter *****
+cjo = 1.584e-11	   m = 3.565e-1		  vj = 6.526e-1 
+ fc = 0.5
***** temperature coefficient *****
+tnom = 25		  eg = 1.113		 xti = 3
+trs1 = -2.335e-4	trs2 = 1.085e-6		tikf = 1.0e-2
+tbv1 = 8.583e-4	tbv2 = -2.101e-7	
.ends MMSZ5256B
*$
